BorlandTalk.com

Philip E. Jurgenson · Guest

D2006
TeeChart Standard CodeGear Edition

I've been trying to figure out how to display a single mark for a value
in a bar chart when the mouse moves over a bar. No problem figuring out
which series is referenced, and it's not a problem to figure out which
individual mark is represented by the bar. However, despite the fact
that each mark (TMarksItem) has a "Visible" property, it doesn't seem
to work in a way that's _implied_ by the help file.

I've tried setting the series' Marks.Visible := True and then setting
each individual mark (Marks.Item[xx].Visible := False) to not visible -
that doesn't seem to work. I've even gone so far as to change the font
color to match the background, then on the MouseEnter event change the
font color to something visible, and changing it again in the
MouseLeave event. This sort of works, but not very well.

Has anybody tried to do this sort of thing? It's for an application
that only I use, and isn't important enough to spend the money to
upgrade to a version with source. Still, I'd like to know whether this
is possible or not - it'll bug me until I know one way or another! :-)

Any suggestions appreciated - Thanks!

Phil

--

David Berneda · Guest

Hi Philip
Instead of using the MarksItem Visible property you might want to try using
the Series1 "OnGetMarkText" event, and setting the string parameter to empty
string for the marks you want to hide.

See the code below, I think it does what you need.

You might also want to submit your question at our support forms or public
newsgroups so we can verify if the Marksitem Visible property is working
correctly or not.

http://www.steema.com/products/support/support_agreements.html

regards
david
www.teechart.com

var
Current : Integer=-1;

procedure TForm1.Chart1MouseMove(Sender: TObject; Shift: TShiftState; X,
Y: Integer);
var tmp : Integer;
begin
tmp:=Series1.Clicked(x,y);

if tmp<>Current then
begin
Current:=tmp;
Series1.Repaint;
end;
end;

procedure TForm1.Series1GetMarkText(Sender: TChartSeries;
ValueIndex: Integer; var MarkText: String);
begin
if ValueIndex <> Current then
MarkText:='';
end;

"Philip E. Jurgenson" <pejurgen (AT) hickorytech (DOT) net> wrote in message
news:4607cdfa (AT) newsgroups (DOT) borland.com...

Philip E. Jurgenson · Guest

David Berneda wrote:

Yeray Alonso · Guest

Hello Phiplip,
you can do something like following code. I hope it helps. And I'll post
another answer at steema newsgroups with the project as an attachment.

//************************************************* Unit1.pas
unit Unit1;

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, Series, TeEngine, TeeProcs, Chart, ExtCtrls, TeeComma;

type
TForm1 = class(TForm)
TeeCommander1: TTeeCommander;
Chart1: TChart;
Series1: TBarSeries;
Series2: TBarSeries;
Series3: TBarSeries;
Series4: TLineSeries;
procedure FormCreate(Sender: TObject);
procedure Series1GetMarkText(Sender: TChartSeries; ValueIndex: Integer;
var MarkText: String);
procedure Chart1MouseMove(Sender: TObject; Shift: TShiftState; X,
Y: Integer);
private
{ Private declarations }
public
{ Public declarations }
end;

var
Form1: TForm1;
Current: Integer=-1;
CurrSeries: Integer;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var i: Integer;
begin
for i:=0 to Chart1.SeriesCount-1 do
begin
Chart1[i].FillSampleValues();
Chart1[i].Marks.Visible:=true;
Chart1[i].OnGetMarkText:= Series1GetMarkText;
end
end;

procedure TForm1.Series1GetMarkText(Sender: TChartSeries;
ValueIndex: Integer; var MarkText: String);
begin
if ((ValueIndex <> Current) or (Sender <> Chart1[CurrSeries])) then
MarkText:='';
end;

procedure TForm1.Chart1MouseMove(Sender: TObject; Shift: TShiftState; X,
Y: Integer);
var i, tmp: Integer;
begin
//Descending loop to consider series ZOrder.
for i:=Chart1.SeriesCount-1 downto 0 do
begin
tmp:=Chart1[i].Clicked(X,Y);

if tmp<>-1 then
begin
Current:=tmp;
CurrSeries:=i;
Chart1[i].Repaint;
break;
end;
end;

end;

end.
//************************************************* end of Unit1.pas

--
Best Regards
Yeray Alonso

Steema Support Central
http://support.steema.com
_______________________

"Philip E. Jurgenson" <pejurgen (AT) hickorytech (DOT) net> wrote in message
news:46080725 (AT) newsgroups (DOT) borland.com...

Philip E. Jurgenson · Guest

Yeray Alonso wrote:

Narcís Calvet · Guest

Hi Philip,

This is just a trick to achieve what you requested. The proper way to
achieve this automatically is using MarkTips tool which is included in
TeeChart Pro v7 VCL

--
Best Regards,

Narcis Calvet
Steema Support Central
http://support.steema.com

"Important note: If you are a TeeChart registered customer, please post your
support questions at Steema's Support monitored Forums for customers:
http://support.steema.com for a prompter reply."

Philip E. Jurgenson wrote: