BorlandTalk.com

Sanyin · Guest

I want to optimize this:
Any tips?MMX, SSE or asm?

function YCCKtoColor32(Y, Cb, Cr, K: integer): tcolor32;
var _k,_y,_cb,_cr: Integer;
val: single;
gm: single;
begin
with tcolor32entry(RESULT) do
begin
gm:=0.65;
_k := 220 - K;
_y := 255 - Y;
_cb := 255 - Cb;
_cr := 255 - Cr;

val := _y + 1.402 * (_cr - 128) - _k;
val := (val - 128) * gm + 128;
if val < 0 then r:= 0 else
if val > 255 then r:=255 else
r:=round(val + 0.5);

val := _y - 0.34414 * (_cb - 128) - 0.71414 * (_cr - 128) - _k;
val := (val - 128) * gm + 128;
if val < 0 then g:=0 else
if val > 255 then g:=255 else
g:=round(val + 0.5);

val := _y + 1.772 * (_cb - 128) - _k;
val := (val - 128) *gm + 128;
if val < 0 then b:= 0 else
if val > 255 then b:=255 else
b:=round(val + 0.5);

a:=255;
end
end ;

Bob Gonder · Guest

Sanyin wrote:

Davy Landman · Guest

sdasdasf · Guest

"Bob Gonder" <notbg (AT) notmindspring (DOT) invalid> wrote in message
news:5orj43l661ajbj8lvqm9ivj20tsfqpik9a (AT) 4ax (DOT) com...

Bob Gonder · Guest

Davy Landman wrote:

Davy Landman · Guest

Michael Hansen · Guest

Bob Gonder wrote:

Nils Haeck · Guest

From my Jpeg library:

No multiplies, just int additions, shifts and table lookups. If you want to
use this code you'll have to acknowledge with my name and company (Nils
Haeck, www.simdesign.nl)

(call InitYCbCrToRGBTables in initialization section)

Hope that helps,

Nils

const
cColorConvScale = 1 shl 10;
c__toR = Round( -179.456 * cColorConvScale);
c__toG = Round(135.53664 * cColorConvScale);
c__toB = Round( -226.816 * cColorConvScale);

var
cY_toRT: array[0..255] of integer;
cCrtoRT: array[0..255] of integer;
cCbtoGT: array[0..255] of integer;
cCrtoGT: array[0..255] of integer;
cCbtoBT: array[0..255] of integer;

procedure InitYCbCrToRGBTables;
var
i: integer;
begin
for i := 0 to 255 do begin
cY_toRT[i] := Round( 1 * cColorConvScale * i);
cCrtoRT[i] := Round( 1.402 * cColorConvScale * i);
cCbtoGT[i] := Round( -0.34414 * cColorConvScale * i);
cCrtoGT[i] := Round( -0.71414 * cColorConvScale * i);
cCbtoBT[i] := Round( 1.772 * cColorConvScale * i);
end;
end;

procedure TsdTransformYCCKToRGB.Transform(Source, Dest: pointer; Count:
integer);
// YCCK is a colorspace where the CMY part of CMYK is first converted to
RGB, then
// transformed to YCbCr as usual. The K part is appended without any
changes.
// To transform back, we do the YCbCr -> RGB transform, then add K
var
R, G, B, Y, Cb, Cr, K: PByte;
Yi, Ki, Ri, Gi, Bi: integer;
function RangeLimit(A: integer): integer;
begin
// Delphi seems to convert the "div" here to SAR just fine (D7), so we
// don't use ASM but plain pascal
Result := A div (1 shl 10);
if Result < 0 then
Result := 0
else
if Result > 255 then
Result := 255;
end;
begin
Y := Source;
Cb := Source; inc(Cb);
Cr := Source; inc(Cr, 2);
K := Source; inc(K, 3);
// RGB is layed out in memory as BGR
B := Dest;
G := Dest; inc(G);
R := Dest; inc(R, 2);
// Repeat Count times..
while Count > 0 do
begin
// Do the conversion in int
Yi := cY_toRT[Y^];
Ki := cY_toRT[K^];
// The components seem to be inverted. Seems to be a Photoshop problem.
Ri := -Yi - cCrtoRT[Cr^] - c__toR + Ki;
Gi := -Yi - cCbToGT[Cb^] - cCrtoGT[Cr^] - c__toG + Ki;
Bi := -Yi - cCbtoBT[Cb^] - c__toB + Ki;
R^ := RangeLimit(Ri);
G^ := RangeLimit(Gi);
B^ := RangeLimit(Bi);
// Advance pointers
inc(Y, 4); inc(Cb, 4); inc(Cr, 4); inc(K, 4);
inc(R, 3); inc(G, 3); inc(B, 3);
dec(Count);
end;
end;

"Sanyin" <prevodilac (AT) hotmail (DOT) com> schreef in bericht
news:4649c1d8 (AT) newsgroups (DOT) borland.com...

Sanyin · Guest

I dont know for that Adobe problem (inverted YCCK).
Saving with Photoshop 7, CS, CS2 etc. produces YCCK jpeg?
I think its correct, at least with my functions there are no problens
decoding it.

Sanyin · Guest

"Nils Haeck" <bla (AT) bla (DOT) com> wrote in message
news:464aede1$1 (AT) newsgroups (DOT) borland.com...

Nils Haeck · Guest

Can you send me some test images by email?

Nils

Nils Haeck · Guest

Nils Haeck · Guest

This conversion should be correct.. can you test? It adds a few int
multiplications, which can be avoided by adding another set of tables. But I
don't want to do that before I know for sure this one works.

Nils

procedure TsdTransformYCCKToRGBAdobe.Transform(Source, Dest: pointer;
Count: integer);
// YCCK to RGB for Adobe images is different. First, the Y, Cr and Cb are
inverted,
// and k* = 220 - K. The normal YCbCr to RGB is then applied. As a last
step,
// the values are scaled by 0.65 around 128
const
c0_65: integer = round(0.65 * cColorConvScale);
c44_8: integer = round(44.8 * cColorConvScale);// 128 - 0.65 * 128
var
R, G, B, Y, Cb, Cr, K: PByte;
Yi, Ki, Ri, Gi, Bi, Cbi, Cri: integer;
function ScaleAndRangeLimit(A: integer): integer;
begin
// First the scaling
A := (A * c0_65) div cColorConvScale + c44_8;
// Undo fixed precision and range limit
Result := A div cColorConvScale;
if Result < 0 then
Result := 0
else
if Result > 255 then
Result := 255;
end;
begin
Y := Source;
Cb := Source; inc(Cb);
Cr := Source; inc(Cr, 2);
K := Source; inc(K, 3);
// RGB is layed out in memory as BGR
B := Dest;
G := Dest; inc(G);
R := Dest; inc(R, 2);
// Repeat Count times..
while Count > 0 do
begin
// Do the conversion in int
Yi := cY_toRT[255 - Y^];
Cbi := 255 - Cb^;
Cri := 255 - Cr^;
Ki := (220 - K^) * cColorConvScale;
Ri := Yi + cCrtoRT[Cri] + c__toR - Ki;
Gi := Yi + cCbToGT[Cbi] + cCrtoGT[Cri] + c__toG - Ki;
Bi := Yi + cCbtoBT[Cbi] + c__toB - Ki;
R^ := ScaleAndRangeLimit(Ri);
G^ := ScaleAndRangeLimit(Gi);
B^ := ScaleAndRangeLimit(Bi);
// Advance pointers
inc(Y, 4); inc(Cb, 4); inc(Cr, 4); inc(K, 4);
inc(R, 3); inc(G, 3); inc(B, 3);
dec(Count);
end;
end;

Sanyin · Guest

I think it shold be done with color management.

Nils Haeck · Guest

Well most CMYK's I saw indeed contain an ICC colour profile. You can extract
that with my lib, but then you need something like Little CMS to actually
use it. ICC colour profiles in these CMYK Jpegs can be quite large.. spread
over e.g. 15 meta tags each containing 32K or so. So indeed there may be
valuable information in there :)

Nils